QuickBox2Dの小ネタ。
運動の状態を保持したままオブジェクトを平行移動や回転させるには、
QuickObjectインスタンスのx、y、angleプロパティを変更すれば良いみたい。
あるオブジェクトのQuickObjectインスタンスはaddしたときに戻り値として受け取れる。
Box2DFlashAS3のSetXFormを使うよりも簡単で便利。

以下サンプルのソースコード（実行には別途Tweenerが必要です）

import com.actionsnippet.qbox.*;
import caurina.transitions.Tweener;

//初期化
var sim:QuickBox2D = new QuickBox2D(this);
sim.setDefault( { fillColor:0x0, lineAlpha:0 } );

//地面を作る
sim.addBox( { x:10, y:13, width:30, height:0.1, density:0 } );

//円を3つ作って配列 _circles に入れておく
var circles:Array = new Array();
circles.push( sim.addCircle( { x:4 , y:8, radius:0.3, isBullet:true } ) );
circles.push( sim.addCircle( { x:6 , y:8, radius:0.6, isBullet:true } ) );
circles.push( sim.addCircle( { x:8 , y:8, radius:1.0, isBullet:true } ) );

//バーを作って変数 _bar に入れておく
var bar:QuickObject = sim.addBox( { x:9, y:5, width:4, height:0.2, angle:0.3, density:0, fillColor:0xcc0000 } );

//シミュレーション開始
sim.start();
sim.mouseDrag();

//各種イベントリスナの登録
addEventListener(Event.ENTER_FRAME, enterFrameHandler);
stage.addEventListener(MouseEvent.CLICK, stageClickHandler);

//円をループさせる処理
function enterFrameHandler(e:Event):void
{
    var sw:Number = stage.stageWidth / 30;

    //全ての円を走査する
    for each(var b:QuickObject in circles)
    {
        var r:Number = b.params.radius;

        //左端から出たら右端に移動させる
        if (b.x < -r    ) b.x = sw + r;
        else
        //右端から出たら左端に移動させる
        if (b.x > sw + r) b.x = -r;
    }
}

//ステージがクリックされたときにバーを回転させる処理
function stageClickHandler(e:MouseEvent):void
{
    //バーの角度を変更
    Tweener.addTween(bar, {
        angle:bar.angle + ((mouseX / stage.stageWidth) - 0.5) * 10,
        time:1,
        transition:"easeOutQuart"
    } );
}

他のQuickBox2Dネタ一覧もどうぞ » tag : QuickBox2D

なるほど。
categoryBitsとmaskBitsを両方指定しないといけなかったのか。

QuickBox2DやBox2DFlashAS3でのオブジェクト同士の衝突判定をコントロールする話。
そもそもBox2DFlashAS3には（多分Box2Dにも）2種類の衝突判定方法が用意されている。
(1) groupIndexを使う方法
(2) categoryBits、maskBitsの組み合わせを使う方法

(1) groupIndexを使う方法

• 同じ正の数でグループ付けされたオブジェクトは必ず衝突する
• 同じ負の数でグループ付けされたオブジェクトは必ず衝突しない

デフォルトは0で、このときは次に書くcategoryBits、maskBitsの組み合わせを使う方法が優先される。0以外の数値を記述するとgroupIndexの方法が優先される。

(2) categoryBits、maskBitsの組み合わせを使う方法

• categoryBitsに、自分が所属するグループを記述する（デフォルトは0×0001）
• maskBitsに、自分と衝突が起こるグループを記述する（デフォルトは0xffff）

(2)のcategoryBits、maskBitsの組み合わせを使う方法についてちょっと解説。
自分と何かが衝突するかどうかは、自分のmaskBitsと相手のcategoryBitsの論理積をとって計算できる。結果が0なら衝突しない、0以外なら衝突する。

サンプルのソースコードは以下

import com.actionsnippet.qbox.*;

var sim:QuickBox2D = new QuickBox2D(this);
sim.setDefault( { lineAlpha:0, fillAlpha:0.5 } );

// 壁 （デフォルト値を使用）
// categoryBits = 0x0001 (0000 0000 0000 0001)
// maskBits     = 0xffff (1111 1111 1111 1111)
sim.createStageWalls( { fillColor:0xCCCCCC } );

var i:uint;

// ●
// categoryBits 0000 0000 0000 0010
// maskBits     0000 0000 0000 0111
for (i = 0; i < 3; ++i)
{
    sim.addCircle( { x:0.8 + 1.2 + i * 6, y:2, radius:0.5, fillColor:0xFF0000, categoryBits:0x0002, maskBits:0x0007 } );
}
sim.addBox( { x:3.2, y:5, width:3, height:3, density:0, fillColor:0xFF0000, categoryBits:0x0002, maskBits:0x0007 } );

// ▲
// categoryBits = 0x0002 (0000 0000 0000 0010)
// maskBits     = 0x0007 (0000 0000 0000 0111)
for (i = 0; i < 3; ++i)
{
    sim.addPoly( { x:0.8 + 2.4 + i * 6, y:2, verts:[[0, 0, 0.5, 0.87, -0.5, 0.87]], fillColor:0x00CC00, categoryBits:0x0004, maskBits:0x0007 } );
}
sim.addBox( { x:9.2, y:5, width:3, height:3, density:0, fillColor:0x00CC00, categoryBits:0x0004, maskBits:0x0007 } );

// ■
// categoryBits = 0x0008 (0000 0000 0000 1000)
// maskBits     = 0x0001 (0000 0000 0000 0001)
for (i = 0; i < 3; ++i)
{
    sim.addBox( { x:0.8 + 3.6 + i * 6, y:2, width:1, height:1, fillColor:0x0000FF, categoryBits:0x0008, maskBits:0x0001 } );
}
sim.addBox( { x:15.2, y:5, width:3, height:3, density:0, fillColor:0x0000FF, categoryBits:0x0008, maskBits:0x0001 } );

sim.start();
sim.mouseDrag();

QuickBox2Dを使う場合は上記サンプルのように、オブジェクトをaddするときに
maskBits
categoryBits
groupIndex
パラメータを指定する。

Box2DFlashAS3ならば
b2ShapeDef.filter.groupIndex
b2ShapeDef.filter.categoryBits
b2ShapeDef.filter.maskBits
を設定。

参考にさせていただいたページ
物理エンジンライブラリ Box2DFlashAS3 衝突判定と衝突のグループ・カテゴリ分け
Box2D:衝突判定のグループ分け
　

他のQuickBox2Dネタ一覧もどうぞ » tag : QuickBox2D

Zevan Rosser氏が作ってる、簡単にBox2DAS3を使うためのライブラリ「QuickBox2D」のチュートリアル。

第一回は、僕の勉強も兼ねて、QuickBox2Dの導入方法と簡単なサンプルの説明です。

メニューはこちら
QuickBox2Dの導入
サンプルファイルのダウンロード
Sample 01 「四角形と円を作ってみる」
Sample 02 「高精度な衝突判定を使う」
Sample 03 「オブジェクトの色や透明度を変える」
Sample 04 「パラメータのデフォルト値を設定する」
Sample 05 「静的オブジェクトを作る」
Sample 06 「多角形を作る」
Sample 07 「複雑な多角形を作る」
Sample 08 「Box2Dのデバッグ表示を使う」
　

導入
まず、QuickBox2Dライブラリを使うには手元にQuickBox2DライブラリとBox2DFlashAS3ライブラリが必要なので、以下のページからそれぞれダウンロードします。

QuickBox2D – Downloadsにある最新版をダウンロード（6月27日現在でQuickBox2D alpha 107）
Box2DFlashAS3 – 緑色のDownloadボタンからダウンロード

ダウンロードしたファイルを解凍し、クラスパスを通します。
めんどうならflaファイルが置いてあるところにBox2Dフォルダとcomフォルダを置けばOK。
導入はこれで完了。
　

サンプル
今回紹介するサンプルのFlashDevelop用プロジェクトファイル一式をダウンロードできます。
Download

以下では，QuickBox2Dのスタートページに載っている8個のサンプルコードを上から順番に説明していきます。
基本的には本家のソースコードそのままですが、とても簡単に物理シミュレーションを実現できる事が分かると思います。
コードはタイムラインに書いてもクラスのコンストラクタに書いてもOK。
赤文字はそのサンプルで大事な部分です。ではどうぞ。
　

Sample 01 「四角形と円を作ってみる」

import com.actionsnippet.qbox.*; // (1)

var sim:QuickBox2D = new QuickBox2D(this);　// (2)

sim.createStageWalls(); // (3)

sim.addBox( { x:5, y:5, width:1, height:1 } ); // (4)

sim.addCircle( { x:4, y:8, radius:2 } ); // (5)

sim.start(); // (6)

sim.mouseDrag(); // (7)

実行結果

真っ赤っか（笑）　はい、ひとつずついきまーす。

import com.actionsnippet.qbox.*;

(1)　QuickBox2Dのインポート。これがないと始まらない。Box2DFlashAS3はインポートしなくてもQuickBox2Dが勝手にやってくれるのでOK。

var sim:QuickBox2D = new QuickBox2D(this);

(2)　QuickBox2Dインスタンスを作る。こいつの中で物理シミュレーションする。引数として渡したMovieClipにシミュレーション結果をバリバリ描画していく。クラスベースでやるときはついついSprite型を渡してしまわないように注意（笑）

sim.createStageWalls();

(3)　とても便利なメソッド。こいつを呼び出せばステージ四方に壁を作ってくれる。ブラウザリサイズに対応してなかったり厚みをコントロールできなかったりするのがあれだけど、とりあえず実験するぶんにはかなり重宝。

sim.addBox( { x:5, y:5, width:1, height:1 } );

(4)　四角形のオブジェクトを作る。Box2DFlashAS3でなにか作るには、まず形状の定義をして、それから実体化する手順がいるけどQuickBox2DではこれひとつでOK。パラメータとしていろんな値を渡せるけど、ひとまず幅1m、高さ1mの四角形をx座標5m、y座標5mの地点に置いてます。

QuickBox2Dでは1mを30ピクセル固定で表現しているので、1ピクセルが1mだと思ってパラメータを指定するとバカでかいオブジェクトが出現してしまいます。なので例えばオブジェクトをx座標90ピクセルに置きたいときは、xのパラメータを3にすればよいです。

sim.addCircle( { x:4, y:8, radius:2 } );

(5)　同じようにして円形のオブジェクトを作る。radiusは半径。要は半径2mの円をx座標4m、y座標8mの地点に置いてます。

sim.start();

(6)　シミュレーションを開始する。これを書いとけば毎フレーム自動でオブジェクトを更新してくれる。Papervision3DでいうところのstartRenderingみたいなもん。

sim.mouseDrag();

(7) これも便利。壁みたいな固定オブジェクト以外のオブジェクトをマウスでドラッグできるようになる。
　

Sample 02 「高精度な衝突判定を使う」

import com.actionsnippet.qbox.*;
var sim:QuickBox2D = new QuickBox2D(this);
sim.createStageWalls();

sim.addBox( { x:5, y:5, width:1, height:1, isBullet:true } );

sim.addCircle( { x:4, y:8, radius:2 } );
sim.start();
sim.mouseDrag();

実行結果

前回との違いはisBulletパラメータをtrueにして渡すだけ。これだけで、この四角形に対しては精度の高い(でも負荷の高い)衝突判定アルゴリズムに切り替わる。試してみると確かにfalseの場合に比べて衝突後の慣性が自然に表現されてて気持ちいいなー。ポイントとなる部分で使うと良いかも。ちなみにBulletは弾丸という意味。
　

Sample 03 「オブジェクトの色や透明度を変える」

import com.actionsnippet.qbox.*;
var sim:QuickBox2D = new QuickBox2D(this);
sim.createStageWalls();

sim.addBox( { x:5, y:5, width:1, height:1, lineColor:0xFF0000, fillColor:0xFFFF00 } );
sim.addCircle( { x:4, y:8, radius:2, fillColor:0xCC0000, fillAlpha:.5, lineThickness:3, lineAlpha:.5 } );

sim.start();
sim.mouseDrag();

実行結果

lineColorで線の色、lineAlphaで線の透明度、lineThicknessで線の太さ、fillColorで塗り色、fillAlphaで塗りの透明度をそれぞれ変更できる。サンプルでは四角形の線の色を赤、塗りの色を黄色、円の塗りの色をグレー、線と塗りの透明度を0.5、線の太さを3に変更してる。
　

Sample 04 「パラメータのデフォルト値を設定する」

import com.actionsnippet.qbox.*;
var sim:QuickBox2D = new QuickBox2D(this);

sim.setDefault( { fillColor:0x00CC22, lineAlpha:0, radius:1.5 } ); // (1)

sim.createStageWalls();

sim.addBox( { x:5, y:5, width:1, height:1, lineColor:0xFF0000, lineAlpha:1 } );
sim.addCircle( { x:4, y:8, radius:2 } );
sim.addCircle( { x:10, y:4, fillColor:0x666666 } ); // (2)

sim.start();
sim.mouseDrag();

実行結果

ほい解説。

sim.setDefault( { fillColor:0x00CC22, lineAlpha:0, radius:1.5 } );

(1) setDefaultメソッドを使えば全オブジェクトに対するデフォルト値を設定できる。ここでは塗りの色を緑、線の透明度を0（表示しない）、半径を1.5mに設定してる。ただしオブジェクトをaddするときのパラメータとデフォルト値では、addするときのパラメータの方が優先される。

sim.addBox( { x:5, y:5, width:1, height:1, lineColor:0xFF0000, lineAlpha:1 } );
sim.addCircle( { x:4, y:8, radius:2 } );
sim.addCircle( { x:10, y:4, fillColor:0x666666 } );

(2) それぞれのオブジェクトをaddするときに、未指定パラメータに関してだけデフォルト値が設定されている。
　

Sample 05 「静的オブジェクトを作る」

import com.actionsnippet.qbox.*;
var sim:QuickBox2D = new QuickBox2D(this);
sim.setDefault( { fillColor:0x00CC22, lineAlpha:0, radius:1.5 } );
sim.createStageWalls();
sim.addBox( { x:5, y:5, width:1, height:1, lineColor:0xFF0000, lineAlpha:1 } );
sim.addCircle( { x:4, y:8, radius:2 } );
sim.addCircle( { x:10, y:4, fillColor:0x666666 } );

sim.addBox( { x:5, y:6, width:4, height:.3, angle:0.3, density:0, fillColor:0xCC0000 } );

sim.start();
sim.mouseDrag();

実行結果

壁のような動かないオブジェクトを作るにはdensityを0にしてあげればOK。densityが0のオブジェクトはmouseDragを実行してもマウスでドラッグできなくなる。ここでは赤いバーを設置。
　

Sample 0６ 「多角形を作る」

import com.actionsnippet.qbox.*;
var sim:QuickBox2D = new QuickBox2D(this);
sim.setDefault( { fillColor:0x00CC22, lineAlpha:0, radius:1.5 } );
sim.createStageWalls();
sim.addBox( { x:5, y:5, width:1, height:1, lineColor:0xFF0000, lineAlpha:1 } );
sim.addCircle( { x:4, y:8, radius:2 } );
sim.addCircle( { x:10, y:4, fillColor:0x666666 } );
sim.addBox( { x:5, y:16, width:4, height:.3, angle:0.3, density:0, fillColor:0xCC0000 } );

sim.addPoly( { x:15, y:8, verts:[[0, 0, 2, 2, 0, 2]], fillColor:0x0000FF } );

sim.start();
sim.mouseDrag();

実行結果

ちょい複雑なので詳しく解説。
好きな形の多角形を作るにはaddPolyを使い、頂点配列をvertsに渡すことで作れる。(x1, y1)、(x2, y2)、(x3, y3)の3点で定義される頂点配列は[x1, y1, x2, y2, x3, y3]となる。3点は最上部の点から書き始めて，時計回りになる順番で書いていく。

ここで書く頂点座標はステージ座標ではなく、オブジェクトを定義するための頂点間の関係を示す座標なので、(0, 0)と書いたからといってステージの(0, 0)に置かれるわけではない。分かりづらければ(0, 0)に最初の点があると思って座標を書いていけばOK。

サンプルでは(0, 0)、(2, 2)、(0, 2)の3点で定義される三角形を作ってx=15、y=8の位置に置いている。vertsが2重配列になっているのは複数の頂点配列を渡せるようにするため(次のサンプルで解説)。

サンプルでは頂点数が3個だけど、頂点数は8個まで増やせる。ただし，凹な形にすると衝突判定がおかしくなるので注意が必要。

もっと複雑な形のオブジェクトを作る場合は，Sample7で解説する3角形の組み合わせで表現する方法や、vertsではなくpointsを用いる方法(後で解説)を使いましょう．
　

Sample 07 「複雑な多角形を作る」

import com.actionsnippet.qbox.*;
var sim:QuickBox2D = new QuickBox2D(this);
sim.setDefault( { fillColor:0x00CC22, lineAlpha:0, radius:1.5 } );
sim.createStageWalls();
sim.addBox( { x:5, y:5, width:1, height:1, lineColor:0xFF0000, lineAlpha:1 } );
sim.addCircle( { x:4, y:8, radius:2 } );
sim.addCircle( { x:10, y:4, fillColor:0x666666 } );
sim.addBox( { x:5, y:16, width:4, height:.3, angle:0.3, density:0, fillColor:0xCC0000 } );

sim.addPoly( { x:15, y:8, verts:[[0, 0, 2, 2, 0, 2], [0, 0, 0, 1, -2, -0.2]], fillColor:0x0000FF } );

sim.start();
sim.mouseDrag();

実行結果

addPolyのvertsに複数の頂点配列を渡せば、複数のポリゴン組み合わさったがオブジェクトを作れる。

サンプルでは(0, 0)、(2, 2)、(0, 2)からなる三角形と、(0, 0)、(0, 1)、(-2, -0.2)からなる三角形を組み合わせたオブジェクトを作ってる。サンプルでは2個のオブジェクトを組み合わせているが，何個でも組み合わせることができる。
　

Sample 08 「Box2Dのデバッグ表示を使う」

import com.actionsnippet.qbox.*;

var sim:QuickBox2D = new QuickBox2D(this, { debug:true } );

sim.setDefault( { fillColor:0x00CC22, lineAlpha:0, radius:1.5 } );
sim.createStageWalls();
sim.addBox( { x:5, y:5, width:1, height:1, lineColor:0xFF0000, lineAlpha:1 } );
sim.addCircle( { x:4, y:8, radius:2 } );
sim.addCircle( { x:10, y:4, fillColor:0x666666 } );
sim.addBox( { x:5, y:16, width:4, height:.3, angle:0.3, density:0, fillColor:0xCC0000 } );
sim.addPoly( { x:15, y:8, verts:[[0, 0, 2, 2, 0, 2], [0, 0, 0, 1, -2, -0.2]], fillColor:0x0000FF } );
sim.start();
sim.mouseDrag();

実行結果

今回最後の解説。
QuickBox2Dのコンストラクタの第2引数にdebug:trueを含むオブジェクト渡せば、Box2Dのデバッグ表示に切り替わる。
　

おつかれさまでした。
以上が、QuickBox2Dをとりあえず使ってみたい人のための導入方法と簡単なサンプルの説明でした。
QuickBox2Dは現在どんどん機能拡張されていたり、おもしろいサンプルが本家でどんどん紹介されているので（GroupとJointの使い方とかFRIM、任意の形を三角ポリゴンに分けてオブジェクトを作る、表示オブジェクトを切り替えるなどなど）、本家に書いてあることはできるだけ紹介していきたいです。あと僕がライブラリのソースコードを読んでて気づいた点やライブラリ拡張の方法とか。

本家のドキュメントも充実していますので、読んでみると良いかも。
　

他のQuickBox2Dネタ一覧もどうぞ » tag : QuickBox2D

前回のエントリに書いたyugop氏の言葉にもろ影響されてますが、美しいものを作りたくなったので、やったった。ActionScript3.0で流体シミュレーション。ついでにサイトトップも更新しました。

実はまともにDisplacementMapFilterを使ったのは初めてでした、うへぁ。流体シミュレーションも初めてだったので色々戸惑ったけど、まあまあおもろいもんが作れた気がするぞ。

どうやってるかというと、基本的なアルゴリズムはblog ViolentCodingさんのを使っていて、それを動画に適用した感じです。で、そのまんまだとマウスを素早く動かすとゼリーみたいにぷるぷるしちゃったので（可愛いけど）、ドロっとするようにアルゴリズムを改造。あとは高速化のためにセルを2次元配列で走査するのではなく、リンクリストを使うように変更しました。他にも色々やった気がするけど、忘れた。

リンクリストってのは、隣のセルを参照として持っておいて、その参照を使って隣へアクセスする方法。配列演算子を使わずに、隣へ隣へとセルの参照をたどることで、まるっとアクセスします。

今回は各セル毎に、forに代わる次セルへの参照と、流体の速度場を更新するための上下左右8方向のセルの参照を持たせました。これがめっぽう速いのなんのなのです。（フレームレートで言うと5フレームくらい違う）

なので、今度から頻繁に配列を回すときはリンクリストを使うようにするとよさげです。ターゲットプレーヤーが10のときにVectorとどっちが速いのか要検証ですが。

あと、この流体表現。
ライブラリは必殺技という精神に基づいて、trick7さんのTeraFireみたいに

alumiFluid(target);

とかで任意のオブジェクトを液状化できると素敵なので現在制作中だったりします。もちろん、汎用流体ライブラリとしても使えるようにするつもりです。需要あるかどうか分からんけど。

wonderflのはソースにコメントを書いてないので、ライブラリ化のときにちゃんとします。少々お待ちを、すみません。

では～。

現在、日比谷パティオでテオ・ヤンセン展が開催されています。何を隠そう僕はテオ・ヤンセンの大ファンなので、アジア圏初の展示会となれば行かないわけにはいきません。
というわけで先週土曜日に行ってきました。

会場内は撮影禁止なのですが、芸術作品にしては珍しくほとんどの作品に自由に触ることができます。しかも、自分で押したり引いたりしてビーチアニマルを歩かせることができます、すごい！だって、プラスチックのチューブと結束からできている巨大な骨組みが、ワシャワシャと動くんですよ、もう感動ですよ感動。子供やカップルに混じって何回も何回も押したり引いたりしましたよ、ええ。歩行メカニズムをニヤニヤしながら解析している様はさぞかし危険人物として写ったことでしょう。行って良かった。

で、本当にびっくりしたんですけど、テオ・ヤンセン本人が会場にいるんです、普通に！そして本人の解説付きで最新のビーチアニマルを動かすデモをしてくれました。これはあとで知ったのですが、本人がいるのは最初の二日間のみらしく、ちょっと無理してでも土曜日に行って良かったです。

（追記）24日もヤンセン本人がデモをおこなう事が決定したそうです。下記参照。
http://hibiya-patio.under.jp/theo/topics/archives/2009/01/124.html

その最新のビーチアニマル（名前忘れてしまった。。。）は羽とたくさんのペットボトルが背中に付いていて恐竜さながらでした。とにかくでかい。体長は10mくらいだったかな。重さは180kgあるらしいです、うひー。背中のペットボトルは何に使うのかというと、風を貯めておく装置なんだそうです。

開設の受け売りですが、他のビーチアニマルが風ではためく羽の動きをそのまま動力として脚部に伝えているのに対して、最新型は羽の動きをポンプの動きに変換してペットボトルに圧縮空気をため込むらしいのです。そして、その圧縮空気で動かしたシリンダーで地面をキックすることで歩くという。ペットボトルロケットの親玉ですね、すげー。しかも、水感知センサーが付いていて（センサーといってもペットボトルとシリンダーみたいなのでつくった、おおよそセンサーとは思えないような物）、海水を検知して自動で進行方向を逆転できる仕組みを取り入れたとか。これによって海に沈まなくてすむのだとか。
ペットボトルとチューブでアナログコンピュータを実装しているとか、凄すぎる。LBP ² どころじゃねー。

本人の英語は全部は聞き取れなかったんですが、とても楽しそうに話していたのが印象的でした。

デモンストレーションのあとは、質問コーナーみたいなのがあって、何故プラスチックチューブだけで生物を作るのかという質問に対しては、人間の体が様々な働きをするタンパク質からできているように、新しい生物も一つの物質から作りたいと思ったのだそうです。なるほどなー。

確かにビーチアニマルを間近で見ると、材料はほとんどプラスチックチューブだったのですが、様々な組み方や加工の仕方で色んなギミックを作っているんです。ギアとか、骨格とか、クランクとか、シリンダーとか全部ですよ。

もう一つ、彼の夢が印象的だったのです。
彼の夢は、自分が死んだ後もずっと、意志をもって動き回るビーチアニマルたちを生み出すこと。
なんだかロマンチックですよね。

通訳さんを通してですが本人とも直接話せたし、図録にもサインしてもらったし、大満足な一日でした。

それにしても、サイン会は限定50人って言ってた割には明らかにそれ以上の人がいたし、その人達一人一人と話したり写真を撮ったり、ヤンセン氏、スタッフさん共々とてもいい方々でした。

4月上旬まで開催しているそうなので是非足を運んでみてはいかがでしょうか。

（おまけ）ヤンセンと僕

1. http://www.strandbeest.com/
2. リトルビッグプラネット。高度な物理演算を搭載したPS3のゲームソフト。持ってないけど、とても楽しそう。